aje_plateau/Plateau.pde

PImage backgroundImage;
Equipe[] equipes;
Position[] positions;
int nombreEquipes = 42;
PFont quicksandFont;
boolean EDITING;

Table table_Cercles, positionTable, scoreboard;
float[] coord_x;
float[] coord_y;
int[] coord_rayon;

void setup() {
  
  size(displayWidth, displayHeight);
  fullScreen(1);
  //randomSeed(3);
  //frameRate(60);
  colorMode(RGB, 255);
  rectMode(CENTER);
  noStroke();
  EDITING=false;
  
  table_Cercles = loadTable("data/positionTable.csv", "header");
  quicksandFont = loadFont("Quicksand-Bold-40.vlw");
  
  backgroundImage = loadImage("backgroundImage.jpg");
  image(backgroundImage, 0, 0, displayWidth, displayHeight);
  
  equipes = new Equipe[nombreEquipes];
  for (int i=0; i<equipes.length; i++) {
     equipes[i] = new Equipe(i);
  }
  
  positions = new Position[table_Cercles.getRowCount()];
  for (int i=0; i<table_Cercles.getRowCount(); i++) {
    positions[i] = new Position(table_Cercles.getInt(i, "id"));
    positions[i].radius = (i==0 || i==table_Cercles.getRowCount()-1)? 145: 60;
    positions[i].posX = table_Cercles.getFloat(i, "posx");
    positions[i].posY = table_Cercles.getFloat(i, "posy");
  }
  
}

void mouseMoved() {
  // pour chaque équipe
  for (int i = 0 ; i < equipes.length; i++) {
    Equipe e = equipes[i];
    Pion p = e.pion;
    
    // calcul de distance entre la souris et le pion
    float distPion = dist(p.posX, p.posY, mouseX, mouseY);
    // calcul de distance entre la souris et l'emplacement d'équipe
    float distEquipe = dist(e.pos_x, e.pos_y, mouseX, mouseY);
    // seuil de collision
    float threshold = p.radius/2;
    
    // si la souris est au delà du seuil de collision et que le pion est dans un état actif
    if (distPion>threshold && distEquipe>threshold && (p.hovered || p.dragged)) {
      // cloture des deux états
      p.dragStop();
      p.hoverStop();
      break;
    
    // si la souris est sous le seuil de collision du pion et qu'il n'est pas déjà dans l'état survolé
    } else if ((distPion<=threshold || distEquipe<=threshold) && !p.hovered) {
      // activation de l'état survolé
      p.hoverStart();
      break;
    }
  }
  
  if (EDITING) {
    for (int i = 0 ; i < positions.length; i++) {
      Position p = positions[i];
      float distPosition = dist(p.posX, p.posY, mouseX, mouseY);
      float threshold = p.radius/2;
      
      if (distPosition>threshold && (p.hovered || p.dragged)) {
        p.dragStop();
        p.hoverStop();
        break;
      } else if (distPosition<=threshold && !p.hovered) {
        p.hoverStart();
        //println(p.posX, p.posY);
        break;
      }
    }
  }
}

void mousePressed() {
  for (int i = 0 ; i < equipes.length; i++) {
    Pion p = equipes[i].pion;
    float d = dist(p.posX, p.posY, mouseX, mouseY);
    if (d<p.radius/2) {
      //println(p.id+1);
      p.dragStart();
      break;
    }
  }
  
  if (EDITING) {
    for (int i = 0 ; i < positions.length; i++) {
      Position p = positions[i];
      float d = dist(p.posX, p.posY, mouseX, mouseY);
      if (d<p.radius/2) {
        //println(p.id+1);
        p.dragStart();
        break;
      }
    }
  }
}


void mouseDragged() {
  for (int i = 0 ; i < equipes.length; i++) {
    Pion p = equipes[i].pion;
    if (p.dragged) {
      p.posX = mouseX+p.offset.x;
      p.posY = mouseY+p.offset.y;
      // cloture de la boucle for, pour ne pas cibler plusieurs pions si c'était possible
      break;
    }
  }
  
  if (EDITING) {
    for (int i = 0 ; i < positions.length; i++) {
      Position p = positions[i];
      if (p.dragged) {
        p.posX = mouseX+p.offset.x;
        p.posY = mouseY+p.offset.y;
        break;
      }
    } 
  }
}


void mouseReleased() {
  for (int i = 0 ; i < equipes.length; i++) {
    Pion p = equipes[i].pion;
    if (p.dragged) {
      p.dragStop();
      equipes[i].setScore(findClosestPositionFrom(p).getScore());
      saveScoreboard();
    }
  }
  
  if (EDITING) {
    for (int i = 0 ; i < positions.length; i++) {
      Position p = positions[i];
      if (p.dragged) {
        p.dragStop();
        savePositionTable();
      }
    }
  }
}

void mouseWheel(MouseEvent event) {
  // pour chaque équipe
  for (int i = 0 ; i < equipes.length; i++) {
    Equipe e = equipes[i];
    Pion p = e.pion;
    
    // calcul de distance entre la souris et l'emplacement d'équipe
    float distEquipe = dist(e.pos_x, e.pos_y, mouseX, mouseY);
    // seuil de collision
    float threshold = p.radius/2;
    // nouveau rayon
    int radius = p.radius + event.getCount()*-5;

    // si la souris est sous le seuil de collision
    if (distEquipe<=threshold && radius>20 && radius<120) {
      p.radius = radius;
    }
  }
}

void savePositionTable() {
  positionTable = new Table();
  
  positionTable.addColumn("id");
  positionTable.addColumn("posx");
  positionTable.addColumn("posy");
  
  for (int i = 0 ; i < positions.length; i++) {
    Position p = positions[i];
    TableRow position = positionTable.addRow();
    
    position.setInt("id", p.id);
    position.setFloat("posx", p.posX);
    position.setFloat("posy", p.posY);
  }
  
  saveTable(positionTable, "data/positionTable.csv", "csv");

}

void saveScoreboard() {
  scoreboard = new Table();
  
  scoreboard.addColumn("equipe");
  scoreboard.addColumn("score");
  
  for (int i = 0 ; i < equipes.length; i++) {
    Equipe e = equipes[i];
    TableRow scoreEquipe = scoreboard.addRow();
    
    scoreEquipe.setInt("equipe", e.id+1);
    scoreEquipe.setInt("score", e.score);
  }
  
  saveTable(scoreboard, "data/scoreboard.csv", "csv");
}

Position findClosestPositionFrom(Pion pion) {
  
  Position closest = positions[0];
  
  for (int i = 0 ; i < positions.length; i++) {
    Position position = positions[i];
    
    float distPion = dist(pion.posX, pion.posY, position.posX, position.posY);
    float distClosest = dist(pion.posX, pion.posY, closest.posX, closest.posY);

    if (distPion<=distClosest) closest = positions[i];
  }
  
  return closest;
}

void draw() {
  image(backgroundImage, 0, 0, displayWidth, displayHeight);
  for (int i = 0 ; i < equipes.length; i++) {
     equipes[i].update();
  }
  
  if (EDITING) {
    for (int i = 0 ; i < positions.length; i++) {
     positions[i].draw();
    }
  }
  
}